Code review Trac/SVN

use 5.16.3;
use Path::Class qw(dir file);

my $dir = dir(shift // ".");

# find root svn directory
my $svn_root = $dir;
while(defined $svn_root) {
    $svn_root = $svn_root->parent;
    last if -d $svn_root->subdir('.svn');
}


my @output = `svn diff -x "-U0" $dir`;

# build a directory structure with comments included
my $all = {};
my $curr;
my $curr_line;
for my $ln (@output) {

    # target file
    if(my ($file, $rev) = $ln =~ /^--- (.*)\s+\(revision (\d+)\)/) {
        my @path = split m{/}, file($file)->relative($svn_root)->as_foreign('Unix');
        my $pos = $all;
        while(my $sec = shift @path) {
            $pos = $pos->{$sec} ||= {};
            $curr = $pos;
        }
        $curr->{rev} = $rev;
    }

    # line
    if(my ($line_no) = $ln =~ /^\@\@ -(\d+)/) {
        $curr_line = $line_no;
    }

    # comments
    if(my ($comment) = $ln =~ /^\+ .*RH:\s*(.*)$/) {
        $curr->{comments} ||= [];
        push @{ $curr->{comments} }, { line => $curr_line, text => $comment };
    }
}

# traverse the structure and build the output
build_trac_markup($all, 0, '');

sub build_trac_markup {
    my ($data, $level, $path, $file) = @_;
    if(defined $data->{rev}) {
        my $rev = $data->{rev};
        for my $cmt (@{ $data->{comments} }) {
            my $line = $cmt->{line};
            my $text = $cmt->{text};
            print "  "x$level . " - " . "[source:$path\@$rev#L$line line $line] - $text\n";
        }
    }
    else {
        for my $ky (sort keys %$data) {
            print "  "x$level . " - " . "$ky\n";
            build_trac_markup($data->{$ky}, $level+1, $path."/".$ky);
        }
    }
}